Linux Basic

This is an interesting little project. However if you simply use a WAIT you may miss open ports. This may not be a problem on the localhost, but it could be on a remote host. A better way of scanning ports would be to handle the sockets events. You only need to add the open port to your list in the Ready event. And also close the port in the same event. You could do something like this in Gambas 2:

PUBLIC Connection AS NEW Socket AS "SocketClient"

PUBLIC SUB ButtonScan_Click()
  DIM portNumber AS Integer
  FOR portNumber = 1 TO 3000
    Connection.Connect("localhost", portNumber)
    ' Wait until the socket is closed
    ' or an error is found
    REPEAT
      WAIT
    UNTIL Connection.Status <= Net.Inactive
  NEXT
END

PUBLIC SUB SocketClient_Ready()
  PRINT "Port open " & Connection.Port & " on " & Connection.Host
  CLOSE #Connection
END

Events on a socket are:

' Fired when the host is found
PUBLIC SUB SocketClient_Found()
  PRINT "Host found " & Connection.Host
END

' Fired when the socket has been opened and you can read/write to the socket
PUBLIC SUB SocketClient_Ready()
  PRINT "Port open " & Connection.Port & " on " & Connection.Host
END

' Fired when there is an error with the socket.
' This includes when the socket cannot be opened
PUBLIC SUB SocketClient_Error()
  ' PRINT "Error opening socket: " & Connection.Status
END

' Fired when there is some data from the server to be read
PUBLIC SUB SocketClient_Read()
  DIM buffer AS String
  READ #Connection, buffer, Lof(Connection)
END

' Fired when the socket is closed by the server
PUBLIC SUB SocketClient_Closed()
  PRINT "socket closed"
END

A slightly better version of the above program. Put it in your startup module of a command line application. You will also need the gb.net component in your project. (The socket syntax is for Gambas 2.)

PUBLIC Connection AS NEW Socket AS "SocketClient"

PUBLIC SUB Main()
  DIM portNumber AS Integer
  FOR portNumber = 1 TO 3000
    Connection.Connect("localhost", portNumber)
    ' Wait until the socket is closed
    ' or an error is found
    REPEAT
      WAIT 0.01
    UNTIL Connection.Status <= Net.Inactive
    IF Connection.Status = Net.HostNotFound THEN
      PRINT "Host not found"
      ' No point in scanning if we can not find the host
      BREAK
    END IF
  NEXT
END

PUBLIC SUB SocketClient_Ready()
  PRINT "Port open " & Connection.Port & " on " & Connection.Host
  CLOSE #Connection
END

well...

i got some updates about this...

The solution above (the last one) makes the scan routine more effective, because i can make it faster and more accurate with it! The ports can be scanned faster and using the socket event SocketClient_Ready, it makes it very accurate detecting "regular" open ports! 

But the same bottleneck still exist on the program. It's the  only think (on this version) that really doesnt work: scanning remote hosts!

On LAN's it's perfect, faster and very accurate, only needs some service detection (...later ), but now, this problem needs to be solve, or the scanner wil only be usefull for LAN scanning

Either external IP's or domains cant be successfully scanned.


Heres the actual "scan core":


'defining connection socket
PUBLIC Connection AS NEW Socket AS "SocketClient"

'setting the screen counter
PUBLIC screenCount AS Integer



PUBLIC SUB btn1_Click()

 
    DIM targethost AS String
    DIM minportas AS Integer
    DIM maxportas AS Integer
   
    'linking host variable with inputs
    targethost = target.text

    'linking port variables with inputs
    minportas = minPort.Text
    maxportas = maxPort.text
   
    'defining screen counter
    screenCount = 0
   
    'defining range for the scan routine
    FOR minportas = minportas TO maxportas
       
          'connects to target host on current port
          Connection.Connect(targethost, minportas)
       
          'waits until connection is closed or error is found
          REPEAT
          WAIT 0.01
          UNTIL Connection.Status <= Net.Inactive
         
          'checks if hostname was found
          IF Connection.Status = Net.HostNotFound THEN
          screen.Add("Hostname not found...", 0)
          BREAK
          ENDIF
         
          'displays current port...
          current.text = minportas
         
          'counts open ports
          openCount.text = screenCount
         
      NEXT
END

PUBLIC SUB SocketClient_Ready()
 
  'found open port...
  screen.Add("Port: " & Connection.Port & "   |   Status: Open", screenCount)
 
  'close the connection
  CLOSE #Connection
 
  'increment screen counter
  screenCount = screenCount + 1
 
 

END



Once again, thanks for your help!

Best regards!

----------------------------------------------------------------------------------------------
EDIT: Download Current Source Package (alpha2)
----------------------------------------------------------------------------------------------

after some thinking, I decided to expand a little bit the netScan project concept!

Now, the new future steps of development for the relase of version 1.0 alpha4 are:

- Implementation of service detection scheme for each open port found...
- Development of Alive hosts discovery scheme, using ping and such...

With those two new "concepts" i'm trying to make it more usable and usefully, making it more than a simple port scanner!

New ideas, suggestion or any feedback are extremely welcome!



ScreenShot of current alpha4 development:



Best regards!